Lyraspace » Actionscript

Apr 15

Another custom Flex preloader but with RSL support

This post has a great article on building a custom Flex preloader which also allows you to handle the progress of the runtime shared libraries that the Flex framework now loads into the users cache.

The DownloadProgressBar component allows you to view the progress of the runtime shared libraries but be aware that it can only tell you about the RSL as it loads and as there may be more than one it is practically impossible to get any indication of how many bytes in total the app is going to load. For this reason you may have seen erratic preloaders out there at the moment using all kinds of colourful language to tell you what it’s doing … “loading assets”, “modules”, “opening the champagne” etc. This is all done to keep the user occupied while each of the elements are loaded.

Then there’s the actual SWF file. Thankfully there are separate events to handle this so if you prefer you can still display the progress of the main SWF and then when it is completed change your display to inform the user that you are “initialising” which shouldn’t be too long after the main SWF has finished. Indeed your dependencies may have finished before the SWF.

I guess the only way to do this accurately is to know up front exactly how many bytes your application is going to load and then as you get the information from ProgressEvent.bytesLoaded from both the SWF and the RSL you can adjust your percentage calculation accordingly. If anyone does know how you can programmatically detect this I’d love to hear it.

Thanks to Bernhard Hirschmann and Jesse Warden for the work they’ve done and purely for my own reference here’s the class …

Custom Preloader for Flex with RSL support

package
{
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.ProgressEvent;
import mx.events.FlexEvent;
import mx.events.RSLEvent;
import mx.preloaders.DownloadProgressBar;
/**
* This class extends the lightweight DownloadProgressBar class. This class
* uses an embedded Flash 8 MovieClip symbol to show preloading.
* For handling both, SWF and RSL download, it separated its download progress
* by handling the appropriate events, i.e. RSLEvent
*
* @author jessewarden
* @author Bernhard Hirschmann (http://coding.bhirschmann.de)
*/
public class Preloader extends DownloadProgressBar
{
/**
* The Flash 8 MovieClip embedded as a Class.
*/
[Embed(source="../assets/flash/preloader.swf", symbol="Preloader")]
private var FlashPreloaderSymbol:Class;
private var clip:MovieClip;
private var isRslDownloading:Boolean = false;
private var rslPercent:Number = 0;
private var swfPercent:Number = 0;
private var rslBytesTotal:Number;
private var rslBytesLoaded:Number = 0;
private var swfBytesTotal:Number;
private var swfBytesLoaded:Number = 0;
public function Preloader()
{
super();
// instantiate the Flash MovieClip, show it, and stop it.
// Remember, AS2 is removed when you embed SWF's,
// even "stop();", so you have to call it manually if you embed.
clip = new FlashPreloaderSymbol();
addChild(clip);
clip.gotoAndStop("start");
}
public override function set preloader(preloader:Sprite):void
{
trace("starting...");
// runtime shared library
preloader.addEventListener( RSLEvent.RSL_PROGRESS, onRSLDownloadProgress );
preloader.addEventListener( RSLEvent.RSL_COMPLETE, onRSLDownloadComplete );
preloader.addEventListener( RSLEvent.RSL_ERROR, onRSLError );
// application
preloader.addEventListener( ProgressEvent.PROGRESS, onSWFDownloadProgress );
preloader.addEventListener( Event.COMPLETE, onSWFDownloadComplete );
// initialization
preloader.addEventListener( FlexEvent.INIT_PROGRESS, onFlexInitProgress );
preloader.addEventListener( FlexEvent.INIT_COMPLETE, onFlexInitComplete );
clip.preloader.rsl_amount_txt.text = clip.preloader.app_amount_txt.text = "0%";
centerPreloader();
}
/**
* Makes sure that the preloader is centered in the center of the app.
*
*/
private function centerPreloader():void
{
x = (stageWidth / 2) - (clip.width / 2);
y = (stageHeight / 2) - (clip.height / 2);
}
/**
* Updates the progress bar.
*/
private function updateProgress():void
{
var p:Number = Math.round( (rslPercent + swfPercent) / 2 );
clip.preloader.gotoAndStop(p);
}
/**
* As the RSL (runime shared library) (frame 2 usually) downloads, this event gets called.
* You can use the values from this event to update your preloader.
* @param event
*
*/
private function onRSLDownloadProgress( event:ProgressEvent ):void
{
isRslDownloading = true;
rslBytesTotal = event.bytesTotal;
rslBytesLoaded = event.bytesLoaded;
rslPercent = Math.round( (rslBytesLoaded / rslBytesTotal) * 100);
trace("onRSLDownloadProgress: rslBytesLoaded " + rslBytesLoaded);
trace("onRSLDownloadProgress: rslBytesTotal " + rslBytesTotal);
trace("onRSLDownloadProgress: " + rslPercent + "%");
clip.preloader.rsl_amount_txt.text = String(rslPercent) + "%";
updateProgress();
}
/**
* When the download of frame 2
* is complete, this event is called.
* This is called before the initializing is done.
* @param event
*
*/
private function onRSLDownloadComplete( event:RSLEvent ):void
{
trace("onRSLDownloadComplete: 100% - bytes total: " + event.bytesTotal);
clip.preloader.gotoAndStop(100);
clip.preloader.rsl_amount_txt.text = "100%";
rslPercent = 100;
}
private function onRSLError( event:RSLEvent ):void
{
trace("onRSLError: " + event.errorText + " - " + event.url);
clip.preloader.status_txt.text = event.errorText;
}
/**
* As the SWF (frame 2 usually) downloads, this event gets called.
* You can use the values from this event to update your preloader.
* @param event
*
*/
private function onSWFDownloadProgress( event:ProgressEvent ):void
{
swfBytesTotal = event.bytesTotal;
swfBytesLoaded = event.bytesLoaded;
if ( isRslDownloading ) {
// as soon as RSL starts downloading the SWF data are added by the RSL values
swfBytesTotal -= rslBytesTotal;
swfBytesLoaded -= rslBytesLoaded;
}
swfPercent = Math.round( (swfBytesLoaded / swfBytesTotal) * 100);
trace("onSWFDownloadProgress: " + swfPercent + "%");
trace("onSWFDownloadProgress: swfBytesLoaded " + swfBytesLoaded);
trace("onSWFDownloadProgress: swfBytesTotal " + swfBytesTotal);
clip.preloader.app_amount_txt.text = String(swfPercent) + "%";
updateProgress();
}
/**
* When the download of frame 2
* is complete, this event is called.
* This is called before the initializing is done.
* @param event
*
*/
private function onSWFDownloadComplete( event:Event ):void
{
trace("onSWFDownloadComplete: 100%");
clip.preloader.gotoAndStop(100);
clip.preloader.app_amount_txt.text = "100%";
swfPercent = 100;
}
/**
* When Flex starts initilizating your application.
* @param event
*
*/
private function onFlexInitProgress( event:FlexEvent ):void
{
//trace("onFlexInitProgress: Initializing...");
try {
clip.preloader.gotoAndStop(100);
clip.preloader.status_txt.text = "Initializing...";
}
catch (e:Error) {
}
}
/**
* When Flex is done initializing, and ready to run your app,
* this function is called.
*
* You're supposed to dispatch a complete event when you are done.
* I chose not to do this immediately, and instead fade out the
* preloader in the MovieClip. As soon as that is done,
* I then dispatch the event. This gives time for the preloader
* to finish it's animation.
* @param event
*
*/
private function onFlexInitComplete( event:FlexEvent ):void
{
trace("onFlexInitComplete");
clip.addFrameScript(21, onDoneAnimating);
clip.gotoAndPlay("fade out");
}
/**
* If the Flash MovieClip is done playing it's animation,
* I stop it and dispatch my event letting Flex know I'm done.
* @param event
*
*/
private function onDoneAnimating():void
{
trace("onDoneAnimating");
clip.stop();
dispatchEvent( new Event( Event.COMPLETE ) );
}
}
}

Apr 15

Custom Preloader class for Flex apps

Actionscript, Flex No Comments »

I’ve blogged on this before but here’s an updated version of a custom preloader class that extends Sprite and loads in a MovieClip from a SWC to use as the animation and display the load progress.

Custom preloader for Flex

package com.cravens.nr.preloader
{
import com.cravens.nr.model.Config;
import flash.display.GradientType;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.ProgressEvent;
import flash.events.TimerEvent;
import flash.geom.Matrix;
import flash.utils.Timer;
import mx.events.FlexEvent;
import mx.preloaders.IPreloaderDisplay;
public class NRPreloader extends Sprite implements IPreloaderDisplay
{
protected var loadingPanel:BusyPanel;
protected var timer:Timer;
public function NRPreloader()
{
super();
}
//------------------------------------------------------------------------------
public function set preloader(preloader:Sprite):void
{
preloader.addEventListener(ProgressEvent.PROGRESS, handleProgress);
preloader.addEventListener(Event.COMPLETE, handleComplete);
preloader.addEventListener(FlexEvent.INIT_PROGRESS, handleInitProgress);
preloader.addEventListener(FlexEvent.INIT_COMPLETE, handleInitComplete);
}
//------------------------------------------------------------------------------
public function initialize():void
{
var matrix:Matrix = new Matrix(0,1,1,0,0,0);
graphics.beginGradientFill(GradientType.LINEAR,[0x000000,0x89265a],[1,1],[125,205],matrix);
graphics.drawRect(0,0,Config.VIEWPORT_WIDTH,Config.VIEWPORT_HEIGHT);
loadingPanel = new BusyPanel();
try
{
loadingPanel.heading_txt.text = "LOADING ... PLEASE WAIT";
loadingPanel.message_txt.text = "0/100%";
}
catch(e:Error)
{
throw new Error("Asset does not contain the relevant textField objects");
}
finally
{
loadingPanel.x = Config.VIEWPORT_CENTER_X-150;
loadingPanel.y = Config.VIEWPORT_CENTER_Y;
addChild(loadingPanel);
}
}
//------------------------------------------------------------------------------
// Define empty event listeners.
private function handleProgress(event:ProgressEvent):void
{
var prog:Number = Math.ceil((event.bytesLoaded/event.bytesTotal)*100);
loadingPanel.message_txt.text = prog+"/100%";
}
//------------------------------------------------------------------------------
private function handleComplete(event:Event):void
{
loadingPanel.message_txt.text = "LAUNCHING";
}
//------------------------------------------------------------------------------
private function handleInitProgress(event:FlexEvent):void
{
}
//------------------------------------------------------------------------------
private function handleInitComplete(event:Event):void
{
timer = new Timer(500,1);
timer.addEventListener(TimerEvent.TIMER, dispatchComplete);
timer.start();
}
//------------------------------------------------------------------------------
private function dispatchComplete(event:TimerEvent):void
{
timer.removeEventListener(TimerEvent.TIMER, dispatchComplete);
timer = null;
dispatchEvent(new Event(Event.COMPLETE));
}
//------------------------------------------------------------------------------
// Implement IPreloaderDisplay interface
public function get backgroundColor():uint
{
return 0;
}
//------------------------------------------------------------------------------
public function set backgroundColor(value:uint):void
{
}
//------------------------------------------------------------------------------
public function get backgroundAlpha():Number
{
return 0;
}
//------------------------------------------------------------------------------
public function set backgroundAlpha(value:Number):void
{
}
//------------------------------------------------------------------------------
public function get backgroundImage():Object
{
return undefined;
}
//------------------------------------------------------------------------------
public function set backgroundImage(value:Object):void {
}
//------------------------------------------------------------------------------
public function get backgroundSize():String {
return "";
}
//------------------------------------------------------------------------------
public function set backgroundSize(value:String):void {
}
//------------------------------------------------------------------------------
public function get stageWidth():Number
{
return Config.VIEWPORT_WIDTH;
}
//------------------------------------------------------------------------------
public function set stageWidth(value:Number):void
{
}
//------------------------------------------------------------------------------
public function get stageHeight():Number
{
return Config.VIEWPORT_HEIGHT;
}
//------------------------------------------------------------------------------
public function set stageHeight(value:Number):void
{
}
}
}

Also, notice I’ve created a simple grad background using the Sprite graphics …

var matrix:Matrix = new Matrix(0,1,1,0,0,0);
graphics.beginGradientFill(GradientType.LINEAR,[0x000000,0x89265a],[1,1],[125,205],matrix);
graphics.drawRect(0,0,Config.VIEWPORT_WIDTH,Config.VIEWPORT_HEIGHT);

This is the best way to do things because remember, the framework has not loaded while the preloader is displayed so you need to keep things lightweight and simple.

Also, the Matrix object rotates the grad so it runs vertically.

Have fun.

Apr 15

Detecting when text has run into the end of a container in a TextFlow object

Actionscript, Flex 3 Comments »

More fun and games with the Text Layout Framework. So, I have a load of links being flowed one by one through a bunch of linked containers. I need to detect when a link reaches the end and has ‘overflowed’ so to speak.

To do this you need to make sure your ContainerController objects have their ScrollPolicy set to OFF so the flowComposer recognises that the text is not in the container anymore. This will not halt the flow however so you need to add a nice bit of code that will detect if the FlowElement is no longer within a container.

Here’s the code …

Detecting when text has run into the end of the ContainerController in a TextFlow object

/*
A good idea to set a config object to pass into the TextFlow object when you create it
*/
config = Configuration(TextFlow.defaultConfiguration).clone();
/*
And add this overflowPolicy to it as well as your formatting defaults
*/
config.overflowPolicy = OverflowPolicy.FIT_DESCENDERS;
textFlow = new TextFlow(config);
/*
Create your containers from sprites and make sure the scrollPolicy is OFF
*/
var controller:ContainerController = new ContainerController(containerSprite,width,height);
controller.verticalScrollPolicy = controller.horizontalScrollPolicy = ScrollPolicy.OFF;
textFlow.flowComposer.addController(controller);
/*
Now imagine we are in a loop which adds a paragraph of lorem ipsum to the textflow and updates the controllers and checks if the flow is now out of the bounds of the container
*/
while(LOOP)
{
textFlow.addChild(myParagraphElement); // you've created the paragraph
textFlow.flowComposer.updateAllControllers(); // you've created the controllers
var containerIndex:int = textFlow.flowComposer.findControllerIndexAtPosition(textFlow.textLength-1);
if(containerIndex==-1) textFlowCompleteHandler();
}

It’s these two lines that do the detection …

var containerIndex:int = textFlow.flowComposer.findControllerIndexAtPosition(textFlow.textLength-1);
if(containerIndex==-1) textFlowCompleteHandler();

The findControllerIndexAtPosition method will return -1 if the character index passed in is not within a container. Remember to use textFlow.textLength-1 to get the last character. The textFlow variable is an instance of the TextFlow object.

The textFlowCompleteHandler can be any method that stops the insertion of FlowElement objects happening.

Apr 07

Crazy code

Actionscript, Flex No Comments »

Sometimes you have to write a method for something crazy complicated. In this snippet I had a container with a load of TextFlow text in it and I needed to zoom into a specific link within the flow while also scaling the container and positioning it within a Scroller viewport without the container going out of the bounds of the Viewport when the link is centered within it.

This is meaningless to anyone but me but sometimes you just have to share the pain.

Zoom in to a link in a TextFlow within a scaled container in a Scroller viewport

private function moveAndZoomToLink(link:LinkElement,p:Person):void
{
var linkStart:int = link.getAbsoluteStart();
var textFlowLine:TextFlowLine = textFlow.flowComposer.findLineAtPosition(linkStart);
var linkPositionOnLine:int = linkStart-textFlowLine.absoluteStart;
var controllerIndex:int = textFlow.flowComposer.findControllerIndexAtPosition(linkStart);
var controller:ContainerController = textFlow.flowComposer.getControllerAt(controllerIndex);
var containerSprite:Sprite = controller.container;
var rect:Rectangle = textFlowLine.getBounds();
var atomRect:Rectangle = textFlowLine.getTextLine().getAtomBounds(linkPositionOnLine+1);
var nameWidth:Number = p.firstName.length*atomRect.width;
var globalAtomRect:Rectangle = new Rectangle(rect.x+(atomRect.x-atomRect.width),rect.y,nameWidth,rect.height);
var box:Shape = new Shape();
box.graphics.beginFill(0xff0000,0.3);
box.graphics.drawRect(globalAtomRect.x,globalAtomRect.y,globalAtomRect.width,globalAtomRect.height);
containerSprite.addChild(box);
var localPosition:Point = new Point();
localPosition.x = containerSprite.x+rect.x+globalAtomRect.x;
localPosition.y = containerSprite.y+rect.y;
/*
We're zooming in so scale the local position
*/
var scaledX:Number = localPosition.x*Config.SHIRT_ZOOM_SCALE;
var scaledY:Number = localPosition.y*Config.SHIRT_ZOOM_SCALE;
/*
We don't want the shirt to move so it is out of the viewport so calculate what this range is ...
*/
var maxMoveX:Number = (Config.SHIRT_WIDTH*Config.SHIRT_ZOOM_SCALE)-Config.VIEWPORT_WIDTH;
var maxMoveY:Number = (Config.SHIRT_HEIGHT*Config.SHIRT_ZOOM_SCALE)-Config.VIEWPORT_HEIGHT;
var newX:Number = 0-scaledX;
var newY:Number = 0-scaledY;
var centeredX:Number = newX+Config.VIEWPORT_CENTER_X;
var centeredY:Number = newY+Config.VIEWPORT_CENTER_Y;
/*
Check the shirt hasn't moved out of bounds
*/
var offsetX:Number = centeredX>0? centeredX*-1 : centeredX<0-maxMoveX? (centeredX*-1)-maxMoveX : 0;
var offsetY:Number = centeredY>0? centeredY*-1 : centeredY<0-maxMoveY? (centeredY*-1)-maxMoveY : 0;
/*
Finally, the new position is nudged so it is at the centre of the viewport space or as near as can be.
*/
moveToPointX = centeredX>0? 0 : centeredX<0-maxMoveX? centeredX+((centeredX*-1)-maxMoveX) : centeredX;
moveToPointY = centeredY>0? 0 : centeredY<0-maxMoveY? centeredY+((centeredY*-1)-maxMoveY) : centeredY;
var viewportX:Number = Config.VIEWPORT_CENTER_X+offsetX;
var viewportY:Number = Config.VIEWPORT_CENTER_Y+offsetY;
shirtMoveTo.play();
var evt:PersonSelectionEvent = new PersonSelectionEvent(PersonSelectionEvent.PERSON_SELECTION,true);
evt.viewportPoint = new Point(viewportX,viewportY);
evt.person = p;
dispatchEvent(evt);
}

Apr 07

Snippety Snipplr snip!

Actionscript No Comments »

So I’ve been using Snipplr recently for storing little code snippets. Looks like a pretty good service but after I tested its embedding features recently in a couple of posts I got sad and started to cry. This is because it didn’t embed very well. Not very well at all. You couldn’t scroll the code horizontally to read it.

Well, I’ve now installed the Snipplr wordpress plugin so hopefully the next bunch of stuff you see will be a couple of Snipplr snippets nicely embedded with some lovely scrolly-pollys scrollbars. Ok, I’ll stop talking like a baby now.

Get the server/domain name that your SWF is running on

/*
In Flex the Application needs to be complete so run this code within your applicationComplete event handler and pass a Boolean into a Data model somewhere so you can use it elsewhere.
*/
var Flex3Application:String = URLUtil.getServerName(Application.application.loaderInfo.url);
var Flex4Application:String = URLUtil.getServerName(FlexGlobals.topLevelApplication.loaderInfo.url);

Detecting if your SWF is running over HTTP or locally

/*
In Flex the Application needs to be complete so run this code within your applicationComplete event handler and pass a Boolean into a Data model somewhere so you can use it elsewhere.
*/
var isLocal:Boolean = loaderInfo.url.indexOf("file") == 0;

There’s a TextMate bundle too.

Exciting ay? The fun never stops here!

Apr 02

How to install the AIR 2 Beta SDK into FlashBuilder 4 and build a cool multi-touch app for your MacBook

Actionscript, Flex No Comments »

Phew … that was a long blog post title! I have to be very specific about this little demo though because if you aren’t on a MacBook with a multi-touch trackpad this demo will not do anything and then you’ll be severely pissed! I’ve not done any tests with Windows so I’m not sure about touch screens or other AIR enabled devices. More information on this here.

Firstly, go and download the latest AIR 2 SDK Beta from here.

The first thing you need to do is duplicate your FB4 SDK folder which you will find in the Application/Adobe Flash Builder 4/sdks/ folder. Then copy the tbz2 download into that folder.

Uploaded with plasq‘s Skitch!

Now you need to uncompress the tbz2 (zip) to the duplicated SDK folder you created. You’ll need to do this in the Terminal app so open it and type ‘cd’ to change the directory and then drag the folder into the terminal to add the path. Then hit return to jump into that folder and enter this text to unzip the package …

tar jxvf AIR20_mac_sdk_*****.tbz2

… replace the asterisks with the version number of the beta you downloaded. You’ll have something like this in your terminal window :

Uploaded with plasq‘s Skitch!

Then hit return and you should see all the files being installed into the appropriate folders.

Now open Flash Builder 4 and go to the preferences to change the SDK. Choose the new SDK folder you duplicated which has now got the new AIR 2 packages installed.

Uploaded with plasq‘s Skitch!

Now create a new Flex AIR project and go to the project preferences to choose your new compiler SDK:

Uploaded with plasq‘s Skitch!

Now you are ready to build a new AIR 2 project with cool multi-touch events! And here’s one I made earlier which demos four of the new TransformGestureEvent Events that you can play with just using the MacBook multi-touch trackpad. It’s basically a small little app of a Monkey that you can scale with a pinch and rotate with a two finger twist. You can also drag him around with a two-finger pan and also make him spring up, down, left and right by swiping on the track pad with three fingers.

Let’s jump straight into the code. I’ve built this in Flex so I use MXML to generate my application window and add a simple Sprite object to the stage using SpriteVisualElement. There’s a simple SWC that contains a Sprite that I created in Flash and exported as ‘Monkey’. This can then be added to the SpriteVisualElement object as a child.

Here’s the full Application class :

If you can see this, your browser doesn’t understand IFRAME. However, we’ll still <a href="http://dev.lyraspace.com/lyraspace/multitouch_test/bin-debug/srcview/source/Main.mxml.html">link</a> you to the file.

View the full source and download the project here.

Grab the AIR file and play on your desktop here. You’ll need the AIR 2 runtime that you can grab here.

If you want to install your tests on an iPhone that’s a blog post for the near future … you can’t do it from within FB4 at the moment and I aint got CS5. My attempts at doing it from the command line failed but I think that’s because it doesn’t like the SWF that FB4 produced. Will look into it.

Hope you enjoy touching my monkey you dirty boys and girls!

Mar 24

Multiple links in a TextFlow object in Flex 4

Actionscript, Flex No Comments »

Flex 4 includes the new Adobe Text Layout Framework (TLF) which is a fantastic new addition that allows greater control of text rendering and the flow of text through containers. You can view the demo material here.

I recently had to use the TLF to generate a whole bunch of links in a stream that flowed through several columns within a composition. The first problem I noticed was that all of the links when chained together were converted to one link. I lost track of how this was fixed but I think it had to do with the links not having href attributes. Anyway, that wasn’t the main problem I encountered. I managed to stream my links together into one long chain and had them nicely justified to the columns :

Uploaded with plasq‘s Skitch!

As you can see I was trying to create a nice wall of links. Eventually these will be names and the user will be able to click on a link for more information etc. Nice! So all it needs is a nice hover state on each link, right? So I add a hover format to the TextFlow and then fell off my chair and sobbed.

Check out the proof-of-concept I created here : http://lyraspace.com/transfer/tlf/TextFlow_POC.html and then read through the posts I wrote on the official forum :

http://forums.adobe.com/message/2682942#2682942
and
http://forums.adobe.com/thread/598789?tstart=0

As you can see, there’s a massive performance issue here with formatting links within a paragraph. It needs to re-draw the paragraph to format the link and with 500 links in the paragraph it’s going to get very sluggish.

The answer then is to create a paragraph for each link? No, this will create a new line for each link.

So I had to work out when a new link would sit on a new line and then create a new paragraph from that link.

And here’s how I did it …

programmatically creating a TextFlow stream of Link Elements

<?xml version="1.0" encoding="utf-8"?>
<s:Application
xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark"
xmlns:mx="library://ns.adobe.com/flex/mx"
xmlns:maps="com.cravens.nr.maps.*"
minWidth="955" minHeight="600"
viewSourceURL="srcview/index.html"
>
<fx:Declarations>
<maps:MainEventMap id="eventMap" />
<maps:ModelMap id="modelMap" />
</fx:Declarations>
<fx:Script>
<![CDATA[
import com.cravens.nr.model.FontsManager;
import flash.text.engine.BreakOpportunity;
import flash.text.engine.FontLookup;
import flash.text.engine.RenderingMode;
import flash.text.engine.TypographicCase;
import flashx.textLayout.compose.TextFlowLine;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.elements.Configuration;
import flashx.textLayout.elements.LinkElement;
import flashx.textLayout.elements.OverflowPolicy;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.SubParagraphGroupElement;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.events.CompositionCompleteEvent;
import flashx.textLayout.events.DamageEvent;
import flashx.textLayout.events.FlowOperationEvent;
import flashx.textLayout.events.UpdateCompleteEvent;
import flashx.textLayout.formats.TextAlign;
import flashx.textLayout.formats.TextLayoutFormat;
import mx.collections.ArrayCollection;
import mx.events.FlexEvent;
import mx.utils.ObjectUtil;
protected var config:Configuration;
protected var paragraphText:String = "";
[Bindable]
protected var textFlow:TextFlow;
[Bindable]
protected var namesArr:ArrayCollection;
protected var linkCount:int = 0;
protected var para:ParagraphElement;
protected var link:LinkElement;
protected var space:SpanElement;
protected var updateDelayTimer:Timer;
//---------------------------------------------------------------------------
public function handleResult(e:Object):void
{
trace("Result:"+ObjectUtil.toString(e));
/*
The XML structure returned from the server maps to an ArrayCollection
*/
namesArr = e.signatures.signature as ArrayCollection;
startTextFlowCreation();
}
//---------------------------------------------------------
public function handleFault(e:Object):void
{
trace("Fault:"+ObjectUtil.toString(e));
}
//---------------------------------------------------------------------------
protected function startTextFlowCreation():void
{
FontsManager.getInstance();
config = Configuration(TextFlow.defaultConfiguration).clone();
var linkNormalFormat:TextLayoutFormat = new TextLayoutFormat();
linkNormalFormat.color = 0x000000;
var linkHoverFormat:TextLayoutFormat = new TextLayoutFormat();
linkHoverFormat.color = 0x999999;
var defaultFormat:TextLayoutFormat = new TextLayoutFormat();
defaultFormat.paddingTop = 6;
defaultFormat.color = 0x333333;
defaultFormat.textAlign = TextAlign.JUSTIFY;
defaultFormat.textAlignLast = TextAlign.JUSTIFY;
defaultFormat.fontSize = 10;
defaultFormat.lineHeight = 12;
defaultFormat.fontLookup = FontLookup.EMBEDDED_CFF;
defaultFormat.typographicCase = TypographicCase.UPPERCASE;
defaultFormat.renderingMode = RenderingMode.CFF;
defaultFormat.fontFamily = FontsManager.NOVAMONO;
config.textFlowInitialFormat = defaultFormat;
config.defaultLinkNormalFormat = linkNormalFormat;
config.defaultLinkHoverFormat = linkHoverFormat;
config.overflowPolicy = OverflowPolicy.FIT_DESCENDERS;
textFlow = new TextFlow(config);
textFlow.columnCount = 4;
para = new ParagraphElement();
textFlow.addChild(para);
updateDelayTimer = new Timer(50,1);
updateDelayTimer.addEventListener(TimerEvent.TIMER_COMPLETE,checkLink);
addLinkElement();
}
//---------------------------------------------------------
protected function addLinkElement():void
{
var o:Object = namesArr[linkCount];
var firstName:String = o.first_name;
var lastName:String = o.last_name;
link = new LinkElement();
link.href = "event:"+o.id;
var linkText:SpanElement = new SpanElement();
linkText.text = o.first_name+" "+o.last_name;
space = new SpanElement();
space.text = " ";
link.addChild(linkText);
para.addChild(link);
para.addChild(space);
textFlow.flowComposer.composeToPosition(textFlow.textLength);
updateDelayTimer.start();
}
//---------------------------------------------------------
protected function checkLink(event:TimerEvent = null):void
{
updateDelayTimer.reset();
if(link)
{
var linkStart:int = link.getAbsoluteStart();
var linkEnd:int = linkStart+link.textLength;
var textFlowLine:TextFlowLine = textFlow.flowComposer.findLineAtPosition(linkStart);
var lineStart:int = textFlowLine.absoluteStart;
var isStartOfLine:Boolean = linkStart==lineStart;
if(isStartOfLine && linkStart!=0)
{
para.removeChild(link);
para.removeChild(space);
para = new ParagraphElement();
textFlow.addChild(para);
para.addChild(link);
para.addChild(space);
}
linkCount++;
if(linkCount == namesArr.length) textFlowComplete();
else addLinkElement();
}
}
//---------------------------------------------------------
protected function textFlowComplete():void
{
updateDelayTimer.removeEventListener(TimerEvent.TIMER_COMPLETE,checkLink);
updateDelayTimer = null;
}
]]>
</fx:Script>
<s:VGroup width="100%" height="100%">
<s:TextArea
id="textArea"
width="100%"
height="100%"
textFlow="{textFlow}"
editable="false"
selectable="false"
/>
</s:VGroup>
</s:Application>

In the example above you have to assume that the names_arr ArrayCollection is loaded in via the Mate framework eventMap and that this collection is made up of objects with a firstName and lastName property that I can use to create the links.

The formatting of the TextFlow can be created in advance by setting up a Configuration object and adding it as an argument while instantiating the TextFlow.

Creating a TextFlow Configuration object

config = Configuration(TextFlow.defaultConfiguration).clone();
var linkNormalFormat:TextLayoutFormat = new TextLayoutFormat();
linkNormalFormat.color = 0x000000;
var linkHoverFormat:TextLayoutFormat = new TextLayoutFormat();
linkHoverFormat.color = 0x999999;
var defaultFormat:TextLayoutFormat = new TextLayoutFormat();
defaultFormat.paddingTop = 6;
defaultFormat.color = 0x333333;
defaultFormat.textAlign = TextAlign.JUSTIFY;
defaultFormat.textAlignLast = TextAlign.JUSTIFY;
defaultFormat.fontSize = 10;
defaultFormat.lineHeight = 12;
defaultFormat.fontLookup = FontLookup.EMBEDDED_CFF;
defaultFormat.typographicCase = TypographicCase.UPPERCASE;
defaultFormat.renderingMode = RenderingMode.CFF;
defaultFormat.fontFamily = FontsManager.NOVAMONO;
config.textFlowInitialFormat = defaultFormat;
config.defaultLinkNormalFormat = linkNormalFormat;
config.defaultLinkHoverFormat = linkHoverFormat;
config.overflowPolicy = OverflowPolicy.FIT_DESCENDERS;
textFlow = new TextFlow(config);

… and then to find the position of the element on the line I used this code :

Finding the position of an element within a TextFlow

var linkStart:int = link.getAbsoluteStart();
var linkEnd:int = linkStart+link.textLength;
var textFlowLine:TextFlowLine = textFlow.flowComposer.findLineAtPosition(linkStart);
var lineStart:int = textFlowLine.absoluteStart;
var isStartOfLine:Boolean = linkStart==lineStart;

As you can see I re-parent the element to a new ParagraphElement object if the LinkElement is at the start of the line.

The Text Layout Framework is still new and there are bugs, this highlights just how erratic the performance can be with it at the moment so handle cautiously and be sure to post your problems on the forum. The guys at Adobe were very helpful and as with all problems like this, you end up learning a hell of a lot about the framework when solving them!

Hey, you might have noticed I’m now using Snipplr to embed my code. I hope it doesn’t disappear any time soon.

Feb 12

Logging Flash with Google Chrome Developer Tools console

Actionscript, Flex No Comments »

Google Chrome’s new Developer Tools panel is really great but now it’s even better now that I’ve managed to log directly into it from Actionscript.

And it’s all thanks to this blog post : http://aut0poietic.us/2008/10/22/using-the-flex-3-logging-framework

All I had to do was create the ExternalConsoleTarget class from his example and then grab the code for the Console Logging wrapper. Then in my project import the Console class and log like this …

Console.debug("Hello Chrome");

It worked for me straight out of the box. Wonderful.

And because I’m a bloody nice bloke here’s my test project which includes a SWC I made so you can use the two classes in your own projects: http://lyraspace.com/tools/ConsoleLogger/Main.html

Feb 11

Removing specific DisplayObjects from a container in Actionscript 3

Actionscript 3 Comments »

This is a common mistake when trying to remove certain DisplayObject objects from a container in Actionscript. I fell into it again today and kicked myself around the office for five minutes afterward.

If you want to remove specific DisplayObjects from a container you may be tempted to do something like this …

for (i=0; i<container_mc.numChildren; i++)
{
if(container.getChildAt(i) == mySprite || container_mc.getChildAt(i) == anotherSprite) container_mc.removeChildAt(i);
}

This will work unless one of the Sprites is at the top of the stack in which case that object wont be removed. But WHY?!!!

Well because the numChildren property will reduce as the objects get removed so eventually it will stop before the last object. The solution is to compensate by adjusting the variable ‘i’ in the for loop. Like so …

for (i=0; i<container_mc.numChildren; i++)
{
if(container.getChildAt(i) == mySprite || container_mc.getChildAt(i) == anotherSprite) { container_mc.removeChildAt(i); i–;}
}

Hope this helps someone and prevents any self-harm.

Oct 09

New touch/gesture events in Actionscript 3 for Flash Player 10.1

Actionscript, Flash, Flex 1 Comment »

This video from a MAX session has an informative demonstration of the new touch/gesture events in 10.1. Also loads of really cool new features in the AIR 2.0 runtime.

What’s coming in Adobe AIR 2.0

Here’s a great article outlining all of the new events, classes and information on how to manage the input.

I’ve scraped the code off this article for my own reference below. Please do read the article though.

flash.ui.Multitouch [static] inputMode:String [static] maxTouchPoints:int [static] supportedGestures:Vector [static] supportsGestureEvents:Boolean [static] supportsTouchEvents:Boolean

Touch Input mode
flash.events.MultitouchInputMode Multitouch.inputMode MultitouchInputMode.TOUCH_POINT MultitouchInputMode.NONE MultitouchInputMode.GESTURE

Mouse
MouseEvent.CLICK MouseEvent.DOUBLE_CLICK MouseEvent.MOUSE_DOWN MouseEvent.MOUSE_UP MouseEvent.MOUSE_MOVE MouseEvent.MOUSE_OUT MouseEvent.MOUSE_OVER MouseEvent.ROLL_OUT MouseEvent.ROLL_OVER

Touch
TouchEvent.TOUCH_BEGIN TouchEvent.TOUCH_MOVE TouchEvent.TOUCH_END TouchEvent.TOUCH_TAP TouchEvent.TOUCH_OUT TouchEvent.TOUCH_OVER TouchEvent.TOUCH_ROLL_OUT TouchEvent.TOUCH_ROLL_OVER TouchEvent.TOUCH_TAP

Touch management

Many multi-touch developers like to use an Object or Array of points to keep track of touch inputs (aka blobs) as well as an ID, and X/Y coordinatees for each point. It looks like Flash Player 10.1 will help you conform to these conventions, ActionScript-style.

flash.utils.Dictionary /* Used to track Arrays of Points */ flash.geom.Point /* One contact point */ TouchEvent.touchPointID /* Unique ID for each touch contact point */ TouchEvent.stageX TouchEvent.stageY TouchEvent.isPrimaryTouchPoint

Gestures
flash.events.GestureEvent; flash.events.GesturePhase; flash.events.GesturePhaseEvent; flash.events.TransformGestureEvent;


/* GestureEvent */

GestureEvent.GESTURE_TWO_FINGER_TAP

GestureEvent.phase: String

GestureEvent.localX:Number

GestureEvent.localY:Number

GestureEvent.stageX:Number

GestureEvent.stageY:Number
/* GesturePhase */

GesturePhase.BEGIN

GesturePhase.END

GesturePhase.UPDATE

/* GesturePhaseEvent */ GesturePhaseEvent.GESTURE_PAN GesturePhaseEvent.GESTURE_PRESS_AND_TAP GesturePhaseEvent.GESTURE_ROTATE GesturePhaseEvent.GESTURE_ZOOM //Is the same thing as 'pinch' GesturePhaseEvent.offsetX:Number GesturePhaseEvent.offsetY:Number GesturePhaseEvent.rotation:Number GesturePhaseEvent.scaleX:Number GesturePhaseEvent.scaleY:Number

Orientation recognition
flash.display.StageOrientation; /* e.g. StageOrientation.DEFAULT */

flash.display.StageDisplayState; /* e.g. stage.displayState = FULL_SCREEN_INTERACTIVE; */

Another custom Flex preloader but with RSL support

Custom Preloader class for Flex apps

Detecting when text has run into the end of a container in a TextFlow object

Crazy code

Snippety Snipplr snip!

How to install the AIR 2 Beta SDK into FlashBuilder 4 and build a cool multi-touch app for your MacBook

Multiple links in a TextFlow object in Flex 4

Logging Flash with Google Chrome Developer Tools console

Removing specific DisplayObjects from a container in Actionscript 3

New touch/gesture events in Actionscript 3 for Flash Player 10.1

Categories

Archives

Posts

Comments

Blogroll

Personal

Twitter Updates

Meta

Recent Posts

Recent Comments

About